1950’s Geiger Counter with Moving Source

Geiger Counter

Speeds up, slows down as if a radioactive source is moving around.

Acts like a 1950’s movie GC with incandescent light bulb indicators. Two channel deluxe model, second channel could actually drive an analog voltmeter with a needle.

//Geiger Counter
//with two channels:
//1. clicks and
//2. average radiation level
//Chn1 is the blinking indicator
//Chn2 is the steady average level, not a true average, but stylized to 
//exaggerate the brightness change from lowrads to highrads.

//blinking lamp
define lightOnTime   100ms
define blinkRiseTime 100ms //incandescent around 80-120ms
define blinkFallTime 120ms //incandescent around 80-120ms

//average indicator lamp, how fast responding
//risetime faster because bulb is "on" for shorter duration
define averagedRiseTime 1400ms 
define averagedFallTime 5000ms

//the sequence

lowrads
@+200ms go to lowrads with 60% chance                 //longer variable time between clicks

        chn1 = fade from 0% to 100% for blinkRiseTime //blink on
        chn2 = fade to 15% within averagedRiseTime    //slow rise

@+lightOnTime 
        chn1 = fade from 100% to 0% for blinkFallTime //blink off
        chn2 = fade to 4% within averagedFallTime     //even slower fall
// <fixedwait> 
@+400ms                                               //long constant time between clicks
          Go To lowrads with 70% chance               //loop, another lowrads click
 //or fall thru to highrads


highrads
@+50ms   Go To highrads with 60% chance                //short variable time between clicks

         chn1 = fade from 0% to 100% for blinkRiseTime //blink on
         chn2 = fade to 100% within averagedRiseTime   //slow rise

@+lightOnTime 
         chn1 = fade from 100% to 0% for blinkFallTime //blink off
         chn2 = fade to 25% within averagedFallTime    //even slower fall

// <fast fixedwait> needs higher chance because it's done faster
@+50ms                                                 //short constant time between clicks
          Go To highrads with 95% chance               //loop, another highrads click
                                                       //higher chance yields 
          //or fall thru to lowrads